Unity 홀로그램 쉐이더

Shader "Custom/Hologram" {
    Properties{
        _Color("Color", Color) = (1,1,1,1)
        _MainTex("Noise", 2D) = "white" {}
        _BumpMap("Normal Map", 2D) = "Bump" {}
    }
    SubShader{
        Tags{ "RenderType" = "Transparent" "Queue"="Transparent" }
 
        CGPROGRAM
 
    #pragma surface surf _CatDarkLight noambient alpha:fade
 
 
    sampler2D _MainTex;
    sampler2D _BumpMap;
 
    struct Input {
        float2 uv_MainTex;
        float2 uv_BumpMap;
    };
 
    fixed4 _Color;
 
    void surf(Input IN, inout SurfaceOutput o) {
        float4 fScanLine = tex2D(_MainTex, IN.uv_MainTex * float2(1.0f, 3.0f) + float2(0.0f, _Time.y*0.1f));
        o.Albedo.rgb = fScanLine.rgb;
 
        float3 fNormal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));
        o.Normal = fNormal;
    }
 
    float4 Lighting_CatDarkLight(SurfaceOutput s, float3 lightDir, float3 viewDir, float attan)
    {
        float3 fHalfVector = 0.0f;
        float fBPSpecular = 0.0f;
 
        fHalfVector = normalize(lightDir + viewDir);
        fBPSpecular = saturate(dot(s.Normal, fHalfVector));
        fBPSpecular = pow(fBPSpecular, 5.0f);
 
        float fFresnel = 1 - abs(dot(viewDir, s.Normal));
 
        fFresnel = pow(fFresnel, 2);
 
        float4 fFinalColor;
        fFinalColor.rgb = (s.Albedo.rgb * _Color * 15.0f) + (fBPSpecular * _LightColor0);
            
        fFinalColor.a = fFresnel * (cos(_Time.y * 4.0f) * 0.5f + 0.7f);
 
        return fFinalColor;
    }
 
    ENDCG
    }
        FallBack "Diffuse"
}